{ stylix, ... }:
let
  wallpapers =
    builtins.mapAttrs
      (
        name: value:
        {
          lib,
          pkgs,
          ...
        }:
        {
          stylix.image = pkgs.fetchurl {
            url = value.url;
            hash = value.hash or lib.fakeHash;
          };
        }
      )
      {
        sekiro.url = "https://w.wallhaven.cc/full/vg/wallhaven-vgor6p.jpg";
        sekiro.hash = "sha256-pcNIr1yON9SsOhUAr//GGbijZayksBTYBu7l+/1+He8=";

        ac-frozen.url = "https://w.wallhaven.cc/full/7p/wallhaven-7p22j9.png";
        ac-frozen.hash = "sha256-qBJL8ddJhUWuUeaqPssMDUSfuNa9elfb7XMMeOAlwpE=";

        ac-impact.url = "https://w.wallhaven.cc/full/jx/wallhaven-jx3xmp.png";
        ac-impact.hash = "sha256-oAm8IVMlZpEuLp1baoFqzFk5VWzELOiOv+CaRIAE2Dc=";

        ac-grid.url = "https://w.wallhaven.cc/full/kx/wallhaven-kxg7d1.png";
        ac-grid.hash = "sha256-7zO4rHrVsFMsnH+X7GJKr6qcGB3Z/k525UIv19lnSls=";

        ludwig.url = "https://w.wallhaven.cc/full/6d/wallhaven-6d8p9w.png";
        ludwig.hash = "sha256-DmV8sF6zN6/A+wQNCaxyQ32aZb4MPsdoKiNDwvnT6qU=";

        wukong.url = "https://w.wallhaven.cc/full/l8/wallhaven-l81moy.jpg";
        wukong.hash = "sha256-EE/VhlbA/hnvjTSvqYLIWay+llNUyZ0iC2OCRphcKkQ=";

        twirly-bh.url = "https://w.wallhaven.cc/full/l8/wallhaven-l8v7kq.jpg";
        twirly-bh.hash = "sha256-on/wIsdUgKSgl9o/jwKu/Rk2ehK9JgDBoGji+QH5b5s=";
      };
in
{
  personal.modules = [
    stylix.nixosModules.stylix
    (
      {
        pkgs,
        config,
        ...
      }:
      {
        stylix.enable = true;

        stylix.polarity = "dark";

        stylix.fonts.monospace.package = pkgs.nerdfonts;
        stylix.fonts.monospace.name = "FiraCode Nerd Font";

        stylix.fonts.sansSerif.package = pkgs.nerdfonts;
        stylix.fonts.sansSerif.name = "Ubuntu Nerd Font";
        stylix.fonts.serif = config.stylix.fonts.sansSerif;

        stylix.fonts.sizes.applications = 10;
        stylix.fonts.sizes.desktop = 12;

        stylix.cursor.package = pkgs.afterglow-cursors-recolored;
        stylix.cursor.name = "Afterglow-Recolored-Dracula-Green";
        stylix.cursor.size = 24;

        stylix.opacity.terminal = 0.9;
      }
    )
  ];
  capsaicin.modules = [
    wallpapers.ac-frozen
  ];
  menthol.modules = [
    wallpapers.ac-grid
  ];
  personal.home_modules = [
    {
      stylix.targets.vscode.enable = false; # it kinda overrides everything with this. which is uncool
    }
    (
      {
        lib,
        pkgs,
        config,
        ...
      }:
      {
        systemd-fuckery.auto-restart = [ "swaybg" ];
        systemd.user.services."swaybg" = {
          Unit = {
            Description = "wallpapers! brought to you by stylix! :3";
            PartOf = [ "graphical-session.target" ];
          };
          Install.WantedBy = [ "graphical-session.target" ];
          Service = {
            ExecStart = "${lib.getExe pkgs.swaybg} -i ${config.stylix.image}";
            Restart = "on-failure";
          };
        };
      }
    )
  ];
}