initial commit. after fucking it up once

adyya-pkgs/adyya_pkgs.mod.nix

@@ -0,0 +1,72 @@
+{
+  aspartame.modules = [
+    (
+      { pkgs, lib, ... }:
+      {
+        nixpkgs.overlays = [
+          (
+            final: prev:
+            let
+              caddy-custom = pkgs.callPackage ./caddy-custom.nix { };
+            in
+            let
+              # Caddy Layer4 modules
+              l4CaddyModules =
+                lib.lists.map
+                  (name: {
+                    inherit name;
+                    repo = "github.com/mholt/caddy-l4";
+                    version = "3d22d6da412883875f573ee4ecca3dbb3fdf0fd0";
+                  })
+                  [
+                    "layer4"
+                    "modules/l4proxy"
+                    "modules/l4tls"
+                    "modules/l4proxyprotocol"
+                  ];
+            in
+            {
+              caddy-default = caddy-custom;
+              caddy-base = caddy-custom.withPlugins { caddyModules = [ ]; };
+              caddy-l4 = caddy-custom.withPlugins {
+                caddyModules = l4CaddyModules;
+                vendorHash = "sha256-Bz2tR1/a2okARCWFEeSEeVUx2mdBe0QKUh5qzKUOF8s=";
+              };
+              caddy-many = caddy-custom.withPlugins {
+                caddyModules = [
+                  {
+                    name = "transform-encoder";
+                    repo = "github.com/caddyserver/transform-encoder";
+                    version = "f627fc4f76334b7aef8d4ed8c99c7e2bcf94ac7d";
+                  }
+                  {
+                    name = "connegmatcher";
+                    repo = "github.com/mpilhlt/caddy-conneg";
+                    version = "v0.1.4";
+                  }
+                ] ++ l4CaddyModules;
+                vendorHash = "sha256-OjyJdcbLMSvgkHKR4xMF0BgsuA5kdKgDgV+ocuNHUf4=";
+              };
+            }
+          )
+        ];
+      }
+    )
+    ({
+      nixpkgs.overlays = [
+        (final: prev: {
+          gts = final.callPackage ./gts.nix { };
+        })
+      ];
+    })
+  ];
+  personal.modules = [
+    ({
+      nixpkgs.overlays = [
+        (final: prev: {
+          beeref = final.callPackage ./beeref.nix { }; # I'M GOING TO TRUNCATE *YOU*, BEEREF.
+        })
+      ];
+    })
+  ];
+}

adyya-pkgs/beeref.nix

@@ -0,0 +1,25 @@
+{
+  appimageTools,
+  fetchurl,
+  lib,
+  ...
+}:
+
+let
+  name = "beeref";
+  version = "0.3.3";
+  src = fetchurl {
+    url = "https://github.com/rbreu/beeref/releases/download/v${version}/${name}-${version}.appimage";
+    hash = "sha256-pavXKtjOvKY2IUPp+UP0v8WkrpPeNEcNDhqoQtFYszo=";
+  };
+in
+appimageTools.wrapType2 {
+  inherit name version src;
+  extraPkgs = pkgs: [ pkgs.python311 ];
+  meta = with lib; {
+    description = "A Simple Reference Image Viewer";
+    homepage = "https://github.com/rbreu/beeref";
+    license = licenses.gpl3Only;
+    mainProgram = "beeref";
+  };
+}

adyya-pkgs/caddy-custom.nix

@@ -0,0 +1,158 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  gnused,
+  installShellFiles,
+  nixosTests,
+  caddy,
+  testers,
+  stdenv,
+}:
+let
+  attrsToModule = map (plugin: plugin.repo);
+  attrsToVersionedModule = map (
+    {
+      repo,
+      version,
+      ...
+    }:
+    lib.escapeShellArg "${repo}@${version}"
+  );
+
+  pname = "caddy";
+  version = "2.8.4";
+
+  dist = fetchFromGitHub {
+    owner = "caddyserver";
+    repo = "dist";
+    rev = "v${version}";
+    hash = "sha256-O4s7PhSUTXoNEIi+zYASx8AgClMC5rs7se863G6w+l0=";
+  };
+
+  src = fetchFromGitHub {
+    owner = "caddyserver";
+    repo = "caddy";
+    rev = "v${version}";
+    hash = "sha256-CBfyqtWp3gYsYwaIxbfXO3AYaBiM7LutLC7uZgYXfkQ=";
+  };
+
+  subPackages = [ "cmd/caddy" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/caddyserver/caddy/v2.CustomVersion=${version}"
+  ];
+
+  # matches upstream since v2.8.0
+  tags = [ "nobadger" ];
+
+  nativeBuildInputs = [
+    gnused
+    installShellFiles
+  ];
+
+  postInstall =
+    ''
+      install -Dm644 ${dist}/init/caddy.service ${dist}/init/caddy-api.service -t $out/lib/systemd/system
+
+      substituteInPlace $out/lib/systemd/system/caddy.service \
+        --replace-fail "/usr/bin/caddy" "$out/bin/caddy"
+      substituteInPlace $out/lib/systemd/system/caddy-api.service \
+        --replace-fail "/usr/bin/caddy" "$out/bin/caddy"
+    ''
+    + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+      # Generating man pages and completions fail on cross-compilation
+      # https://github.com/NixOS/nixpkgs/issues/308283
+
+      $out/bin/caddy manpage --directory manpages
+      installManPage manpages/*
+
+      installShellCompletion --cmd caddy \
+        --bash <($out/bin/caddy completion bash) \
+        --fish <($out/bin/caddy completion fish) \
+        --zsh <($out/bin/caddy completion zsh)
+    '';
+
+  meta = with lib; {
+    homepage = "https://caddyserver.com";
+    description = "Fast and extensible multi-platform HTTP/1-2-3 web server with automatic HTTPS";
+    license = licenses.asl20;
+    mainProgram = "caddy";
+    maintainers = with maintainers; [
+      Br1ght0ne
+      emilylange
+      techknowlogick
+    ];
+  };
+in
+buildGoModule {
+  inherit
+    pname
+    version
+    src
+    subPackages
+    ldflags
+    tags
+    nativeBuildInputs
+    postInstall
+    meta
+    ;
+
+  vendorHash = "sha256-1Api8bBZJ1/oYk4ZGIiwWCSraLzK9L+hsKXkFtk6iVM=";
+
+  passthru = {
+    withPlugins =
+      {
+        caddyModules,
+        vendorHash ? lib.fakeHash,
+      }:
+      buildGoModule {
+        pname = "${caddy.pname}-with-plugins";
+
+        inherit
+          version
+          src
+          subPackages
+          ldflags
+          tags
+          nativeBuildInputs
+          postInstall
+          meta
+          ;
+
+        modBuildPhase = ''
+          for module in ${toString (attrsToModule caddyModules)}; do
+            sed -i "/standard/a _ \"$module\"" ./cmd/caddy/main.go
+          done
+          for plugin in ${toString (attrsToVersionedModule caddyModules)}; do
+            go get $plugin
+          done
+          go mod vendor
+        '';
+
+        modInstallPhase = ''
+          mv -t vendor go.mod go.sum
+          cp -r vendor "$out"
+        '';
+
+        preBuild = ''
+          chmod -R u+w vendor
+          [ -f vendor/go.mod ] && mv -t . vendor/go.{mod,sum}
+          for module in ${toString (attrsToModule caddyModules)}; do
+            sed -i "/standard/a _ \"$module\"" ./cmd/caddy/main.go
+          done
+        '';
+
+        inherit vendorHash;
+      };
+    tests = {
+      inherit (nixosTests) caddy;
+      version = testers.testVersion {
+        command = "${caddy}/bin/caddy version";
+        package = caddy;
+      };
+    };
+  };
+}

adyya-pkgs/gts.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  fetchurl,
+  fetchFromGitHub,
+  buildGoModule,
+  nixosTests,
+}:
+let
+  owner = "superseriousbusiness";
+  repo = "gotosocial";
+
+  version = "0.17.1";
+
+  web-assets = fetchurl {
+    url = "https://github.com/${owner}/${repo}/releases/download/v${version}/${repo}_${version}_web-assets.tar.gz";
+    hash = "sha256-rGntLlIbgfCtdqpD7tnvAY8qwF+BpYbQWfAGMhdOTgY=";
+  };
+in
+buildGoModule rec {
+  inherit version;
+  pname = repo;
+
+  src = fetchFromGitHub {
+    inherit owner repo;
+    rev = "refs/tags/v${version}";
+    hash = "sha256-oWWsCs9jgd244yzWhgLkuHp7kY0BQ8+Ay6KpuBVG+U8=";
+  };
+
+  vendorHash = null;
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.Version=${version}"
+  ];
+
+  tags = [
+    "kvformat"
+  ];
+
+  postInstall = ''
+    tar xf ${web-assets}
+    mkdir -p $out/share/gotosocial
+    mv web $out/share/gotosocial/
+  '';
+
+  # tests are working only on x86_64-linux
+  # doCheck = stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isx86_64;
+  # checks are currently very unstable in our setup, so we should test manually for now
+  doCheck = false;
+
+  checkFlags =
+    let
+      # flaky / broken tests
+      skippedTests = [
+        # See: https://github.com/superseriousbusiness/gotosocial/issues/2651
+        "TestPage/minID,_maxID_and_limit_set"
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+
+  passthru.tests.gotosocial = nixosTests.gotosocial;
+
+  meta = with lib; {
+    homepage = "https://gotosocial.org";
+    changelog = "https://github.com/superseriousbusiness/gotosocial/releases/tag/v${version}";
+    description = "Fast, fun, ActivityPub server, powered by Go";
+    longDescription = ''
+      ActivityPub social network server, written in Golang.
+      You can keep in touch with your friends, post, read, and
+      share images and articles. All without being tracked or
+      advertised to! A light-weight alternative to Mastodon
+      and Pleroma, with support for clients!
+    '';
+    maintainers = with maintainers; [ blakesmith ];
+    license = licenses.agpl3Only;
+  };
+}